*save_checkpoint

*text_image epilogue.png center Epilogue
*temp liveinolympus false
*temp liveinunderworld false
*temp liveinleukas false
*temp enjoyedhadesmoping false
*temp olympusupdate false
*temp underworldupdate false
*temp mortalupdate false
*temp hadesupdate false
*temp patronapproach 1
*temp nonightmares false
*temp peacockbouquet false
*temp extramessenger false
*temp replacement 1
*temp tense false
*temp mustapologize false
*temp hermesnotthere false
*temp onnerves false
*temp proposing false
*temp gifting 1
*temp discourage false
*temp givencrown false


An amber blush peeks over the edge of the sky, heralding the arrival of dawn. By the time it mantles Hellas, the glinting frost will have melted, and the air will have lost its bite.

Their presence confirms what you already know; though winter is coming, it isn't in any rush.

Most of the seeds and crops planted in the spring and nurtured over the summer have been harvested. The trees have begun shedding, but the birds have yet to abandon their nests in search of warmth. Your mother is back in the Underworld, but the land still bears her mark.

*choice
    #I'm glad; the Leukans deserve to catch a break.
        *set mortalupdate true
        *gosub leukasupdate
        *goto main85
    *if giantsuccess = 2
        #I'm glad; Olympus could use the reminder of our might.
            *set olympusupdate true
            *gosub olympusrelationship
            *goto main85
    #I'm glad; my father's moping was getting out of hand.
        *set hadesupdate true
        *gosub hadesmoping
        *goto main85
    #I'm gutted; I was enjoying watching my father mope.
        *set hadesupdate true
        *set enjoyedhadesmoping true
        *gosub hadesmoping
        *goto main85
                 
*label main85
*page_break

@{(flightstyle) You flick your wings, bracing against the wind|You stretch your shadows, bracing against the wind|Wind whips your ankles with every flap of your wings}. Compared to the shifts you were pulling before the Spring Feast, @{(becomemortal) your final nightmare run|this nightmare run} has been a breeze. 

And yet, you can't help but long for home.

Where is home for you, these days?

*choice
    *if chose = 1
        #With Ares, in a cabin in the heart of the oak grove.
            *set liveinolympus true
            *set home 1
            Right on the edge of the stream, with a vast kitchen where Ares bakes and @{(hobby) you weave|you work out|you play your aulos|and the pair of you often lose track of time playing games of petteia}, with a big enough hearth for three or four drakon hatchlings to curl around, and a shaded corner for your Epiali to play.
            *goto olympus
    *if (chose = 1) and (giantsuccess != 2)
        #With Ares, in his newly decorated chambers in Olympus.
            *set home 2
            *set liveinolympus true
            They're not far from the kitchens and overlook the oak grove, but Ares hadn't spent much time there, before.

            "They never felt like home," he'd told you. "Until now."
            
            He had made space for you to @{(hobby) weave|work out|practice the aulos|host game nights} and added a shaded corner for your Epiali to play. 
            
            Frankly, it's been near-impossible to get him to leave since.
            *goto olympus
    *if (chose = 1) or (chose = 3)
        #With @{(chose) Ares|na|Morpheus|na}, in my newly decorated chambers in Elysium.
            *set home 3
            *set liveinunderworld true
            Newly decorated, @{(chose > 1) because Morpheus had insisted on keeping separate storage for your scrolls|because you had insisted on adding a space for the hatchlings, so Ares wouldn't have to keep traveling back and forth to check up on them}.
            *goto movedin
    *if chose = 3
        #With Morpheus, in his newly decorated chambers in the heart of the Erebus mountains.
            *set liveinunderworld true
            *set home 4
            Newly decorated, because Morpheus had insisted on making room for @{(hobby) your loom|working out gear|practice the aulos|you to play the aulos|for you to host game nights}, and on keeping separate storage for your scrolls.
            *goto movedaway
    *if chose = 3
        #With Morpheus, in a cabin by our favorite misty lake.
            *set liveinunderworld true
            *set home 5
            Right on the edge of its glittering surface, with a vast hearth where Morpheus's brothers can gather and where @{(hobby) you can weave|you can work out|you can play your aulos|you can lose track of time playing games of petteia}.

            And not one, but two thrones.
            *goto movedaway
    *if chose = 2
        #With Theron, in his home perched at the top of the hill.
            *set home 6
            *set liveinleukas true
            Where else would the pair of you live? 

            You finally got your own pallet by the hearth, and have experienced what it's like to be subjected to his cousin's terrible poems. To fall asleep under the stars and watch the whole family wake to the smell of freshly-baked honey bread.

            It's better than a dream.
            *goto leukas
    *if chose < 3
        #With @{(chose > 1) Theron|Ares}, in a cabin not far from @{(badfight) where the little temple once stood|the little temple}.
            *set home 7
            *set liveinleukas true
            The pair of you needed a change of scenery, and a space to call your own. 

            It's nothing grand, but there's a sizeable @{(chose > 1) courtyard where Theron whittles|kitchen where Ares bakes} and @{(hobby) you weave|you work out|you play your aulos|and the pair of you often lose track of time playing games of petteia}, and a big enough hearth for @{(chose > 1) his family to gather around and subject you to terrible poems under the stars|three or four drakon hatchlings to curl around, and a shaded corner for your Epiali to play}.
            *goto leukas
    #My own home in Leukas; I needed a change of scenery.
        *set home 8
        *set liveinleukas true
        After so long living under a sky that always stays the same, you're testing out what it's like to watch the land around you change.

        @{(becomemortal) If you are to become mortal, you ought to at least know that, at the very least|It's rather refreshing}.

        *if chose = 4
            *goto leukas
        *else
            Though he visits often, @{(chose) Ares|Theron|Morpheus|na} remains in his own dwellings. Just because you have found love doesn't mean you have to lose your independence.

            Besides, absence makes the heart grow fonder. Your father is proof.
            *if hadesupdate = false
                *gosub hadesmoping
                *goto leukas
            *else
                *goto leukas
    *if becomemortal = false
        #My own chambers in Olympus; I needed a change of scenery.
            *set liveinolympus true
            *set home 9
            After so long dwelling in the shadows, you're testing out living in the light. 

            *if chose = 4
                *goto olympus
            *else
                @{(chose) Separately from Ares.|Yes, Theron can't visit. But just|Much to Morpheus's chagrin. Alas, just|na} because you have found love doesn't mean you have to lose your independence.

                Besides, absence makes the heart grow fonder. Your father is proof.
                *if hadesupdate = false
                    *set hadesupdate true
                    *gosub hadesmoping
                    *goto olympus
                *else
                    *goto olympus
    *if becomemortal = false
        #Where it has always been; Elysium, with my family.
            *set home 10
            *set liveinunderworld true
            Where else would it be? 
            *if chose = 4
                *goto main86
            *else
                Just because you've found love doesn't mean you have to lose your life as you know it. Elysium is your home as much as @{(chose) Ares|Theron|Morpheus|na} is.
                
                Besides, absence makes the heart grow fonder. Your father is proof.
                *if hadesupdate = false
                    *set hadesupdate true
                    *gosub hadesmoping
                    *goto main86
                *else
                    *goto main86
                
*label olympus

*if olympusupdate = false
    *set olympusupdate true
    *gosub olympusrelationship
    *goto olympus2
*else
    *goto olympus2

*label olympus2
*page_break

Your move to Olympus has been met with @{(olympusrelations) not as much suspicion as you might've expected, from the thunder god|nothing but suspicion from the thunder god|great fanfare|little fanfare}.

*label movedaway
*page_break

*if liveinunderworld
    There had been @{(parents > 55) no reluctance from your parents. Only tears|no reluctance from your parents}.
    *goto movedaway1
*else
    @{(liveinunderworld) There|As for your parents, there} had been no @{(parents > 55) reluctance. Only tears|reluctance}.
    *goto movedaway1

*label movedaway1

"There comes a time when a parent must allow their child to find their own way in the world,"
*if parents > 55
    your mother had said when you'd told her, misty-eyed and sighing loudly. "I just wish yours hadn't come so soon."

    Your father had forgone words, and simply wept.

    *fake_choice
        *if liveinunderworld
            #"I'm just down the road," I had reminded them.
        *if becomemortal = false
            #"I'll visit all the time," I had reassured them.
        *if liveinunderworld = false
            #"You'll come visit me all the time," I had made them promise.
        #"Don't make this harder than it needs to be," I had begged them.
        #I had wept too.
    
    The rest of Elysium had reacted 
    *if underworldinfluence > 55
        just as mournfully.
        *goto elysium 
    *else
        with far less fanfare. As though they couldn't care less about where their Princess dwelled.
        *goto main86
*else
    your father had said, barely looking up from his scrolls.

    "Took you long enough," your mother had added, to which you had responded

    *fake_choice
        #"Why do I feel like I'm being kicked out?"
        #"Well, I see you're both heartbroken."
        #"I'll miss the pair of you two, I guess."
        #Nothing. I suppose they're right.

    *if underworldinfluence > 55
        At least the rest of Elysium would mourn your departure from the acropolis.
        *goto elysium
    *else
        And that had been that.
        *goto main86

*label elysium

They had decked the streets with garlands of @{(flower) crocus|daffodil|quince flower|nightshade} in your honor, and had yet to clear their fallen petals from the cobbles.

There had been feasts, games, music and even gifts. Each one special in its own right. 

Each one a testament of your standing in your parents' realm.
*goto main86

*label movedin

Your parents had welcomed him with @{(parents > 55) open arms|little fanfare}.

*if underworldinfluence > 55
    @{(parents > 55) Just like|Unlike} the rest of the Underworld.

    Elysium had thrown many a feast in his honor, complete with @{(chose > 1) poppy garlands and plenty of competitive racing|plenty of ambrosia cake, of course}.
    *goto main86
*else
    @{(parents > 55) They have gone above and beyond to make him feel at home, and you are grateful for their acceptance|Just like the rest of Elysium.}
    *goto main86

*label leukas
*page_break

The Leukans had welcomed you with @{(peoplepleaser > 55) open arms|little fanfare}.

*if mortalupdate
    *goto movedaway
*else
    *set mortalupdate true
    *gosub leukasupdate
    *goto movedaway

*label main86
*page_break

One of your Epili @{(epiali) slithers up to you|squeaks|caws|purrs|crawls up your arm}, reminding you of the meeting you must attend. 

And yet, before you resume your journey to the southern cliffs, you cast a final glance at the land rising and falling beneath you.

*if mortalupdate
    *goto main87
*else
    *set mortalupdate true
    At Leukas.
    *gosub leukasupdate
    *goto main87

*label main87
*page_break Fly To The Southern Cliffs

A rainbow cuts through the bruised sky, brightening your journey to the cave.

"${name}. I was hoping I'd catch you on your way back," Iris greets you when you land on the rock.

Behind their winged silhouette, the dead's whispered warnings spill from @{(becomemortal) the gate. One day, your voice will be among them|the gate}.

*if (giantsuccess != 2) and (olympusinfluence > 55)
    *set peacockbouquet true
    "Hera wished for me to give you this." Iris adds, handing over a bouquet of peacock feathres. 
    *goto giftreaction
*else
    "Aphrodite wished for me to give you this," Iris adds, handing over the biggest, ugliest metal swan you've ever seen.
    *goto giftreaction
*label giftreaction
*if (home = 3) or (home = 10)
    "A token of her appreciation."
    *goto giftreaction1
*else
    "For your new dwellings." 
    *goto giftreaction1

*label giftreaction1
*page_break

You gingerly relieve her of the @{(peacockbouquet) comically large bouquet|hideous contraption}. It weighs more than you do.

What do you respond?

*fake_choice
    *if peacockbouquet
        #"How very generous of her. Will you give her my sincere thanks?"
            Iris nods.
    #"How very…garish of her. I suppose you ought to give her my thanks."
        Iris merely chuckles.
    #"Does she think I live in a palace of my own?"
        Judging by the size and weight of the thing, you wouldn't be surprised.

        Iris merely laughs.
    *if peacockbouquet = false
        #"I see she has found an inventive new way to torment me."
            Iris merely chuckles.
    *if peacockbouquet = false
        #Now I know what to gift Averna for her name day."
            Iris merely chuckles.
    *if peacockbouquet
        #"Now I know what to pawn off onto Aphrodite at the next feast."
            Iris merely chuckles.

*if olympusupdate
    *goto main88
*else
    *gosub olympusrelationship
    *goto main88

*label main88

*if (injuredzagreus = true) and (chose != 4)
    "How is Zagreus doing?" they ask, worry turning their eyes amber.

    There's no need. Thanks to Averna's intervention, he had made a full recovery. He doesn't even seem that bothered about his scar-a nasty ridge that runs from the base of his throat to just above his belly button.

    @{(injured) "Not only are we the family that wears matching crowns, we're also the family that bears matching scars,"|"I think it makes me look more fearsome,"} he'd happily declared when you'd seen him last.

    "He'll live. And be unbearable about it for all eternity," you tell Iris.

    "Good." Their eyes shift towards the gate. "Shall we? I believe Hermes is already there."
    *goto moveon 
*else
    "I believe Hermes is already there," Iris says, gesturing towards the gate.
    *goto moveon

*label moveon

"How very punctual of him."

*page_break Travel Through The Dream Gate

The cries of the damned welcome you @{(liveinunderworld) home, same way they always have|back to your former home}.

*if (home = 10)
    *if underworldinfluence > 55
        The air is still thick with the scent of @{(flower) crocus|daffodil|quince flower|nightshade}.

        Not from your side of the gate, but from the many garlands the realm had hung across Elysium
        *if badfight
            to cheer you up after your failure at the beach. 

            It had been rather reassuring, to see that you still have the realm's support, even if you didn't secure them victory.
            *goto messengers
        *else
            to celebrate your victory at the beach.
            *goto messengers
    *else
        There had been @{(badfight) much disappointement among the Underworld's residents following your failure at the beach|no fanfare to acknowledge your role in the victory at the beach}.

        Whether @{(badfight) they|your realm} will ever see you as a ruler in your own right, and not just Hades and Persephone's daughter, remains to be seen.
        *goto messengers
*else
    Souls wink above you, the Lethe bubbles softly, and mist weaves in and out of the trees.

    @{(liveinunderworld) It's a scene you'll never grow tired of beholding|It has been a while since you last laid eyes on such a scene}.

    *if becomemortal
        After today, it will be even longer until you do so again.
        *goto messengers
    *else
        *goto messengers

*label messengers
*page_break

Iris was right. Hermes is already here. Morpheus, too.

Upon noticing the huge @{(peacockbouquet) peacock bouquet|metal swan}, the latter
*if (chose = 3)
    shoots you a look that says, [i]That is most certainly [/i]not[i] @{(home < 8) coming anywhere near our home.|going in your home, is it?}[/i]

    *if parents > 55
        *set givencrown true
        You shoot him a look back that says, [i]Wouldn't it look nice, next to your new crown?[/i]

        He smirks, but his gaze softens. Now [i]that[/i] had been a great gift alright.
        *gosub crown
        Your chest tightens at the memory as you set this latest, much less welcome, gift down on the moss.
        *goto messengers1
    *else
        You ignore him and set the gift down on the moss.
        *goto messengers1
*else
    smirks. You ignore him and set the gift down on the moss.
    *goto messengers1

*label messengers1

Then you regard your fellow messengers.

You have gathered by the Dream Gate, just like you had that first time, too many mortal lifespans ago to count, to determine the Council's future.

*if becomemortal
    *set extramessenger true
    And it isn't just them.

    Your replacement is among them as well.
    *if respect > 55
        *goto replacement
    *elseif olympusrelations > 2
        *set replacement 1
        Apate, the goddess of deceit, guile and fraud, chosen by the Council to impersonate you.
        *goto replacement2
    *else
        *set replacement 2
        Phobos, the Olympian god of fear, chosen by Zeus himself.
        *goto replacement2
*else
    *goto messengers2

*label replacement
*page_break

When you had announced you were stepping down, the Council had agreed to let you choose who would take your place. 

You, of course, had chosen

*choice
    #Averna. The nymph is fearsome, can travel through shadows, and loves my Epiali.
        *set replacement 3
        It's a perfect fit, a fact proven by how seamlessly she has already made her mark on the group.

        Iris is impressed by her creative approach, Morpheus by her sharp wit.

        @{(hermesleader) Even Hermes is taken with her, and her fondness for fear|Should Hermes resume his position, you have no doubt he'll be taken with her too}.
        *goto messengers2
    #Zagreus. @{(Zagreus > 55) My brother is more than ready for the responsibility|It's high time my brother took responsibility for something other than himself}.
        *set replacement 4
        After Averna taught him how to travel through shadows, the Halfrealm ought to be easy enough to navigate. The fears lurking in its depths might not be as easy a prey as he's used to.

        But he's a hunter, he'll figure it out, in time.
        *goto messengers2
    *if olympusrelations > 2
        #Phobos. The Olympian god of fear ought to do the trick.
            *set replacement 2
            *goto phobos
    #Apate. The goddess of deceit, guile and fraud can easily impersonate me.
        *set replacement 1
        *goto apate

*label replacement2
*page_break 

The @{(replacement > 1) god|goddess} had been chosen without your input. Any efforts on your part to have a say in the matter had been promptly ignored.

Somehow, you doubt the fact you won't be a goddess for much longer had anything to do with it.

*if replacement = 1
    *goto apate
*else
    *goto phobos

*label apate

You glance at the goddess who is to take your place.

She isn't wearing your face, though you have witnessed her trying it on. But @{(flightstyle) a pair of wings that look suspiciously similar to yours sprout from her back|shadows lick the hem of her dress, as though ready to carry her anywhere she may wish|she's wearing a pair of winged sandals that look suspiciously like yours}, and you can feel her studying you with unnerving intensity.

*goto messengers2

*label phobos

You glance at the god who is to take your place. An Olympian through and through, with leonine features including a long, shaggy mane and golden eyes that shimmer against the Underworld's dimmness.

*label messengers2
*page_break Let The Meeting Begin

Hermes clears his throat, drawing everyone's eye.

*if hermesleader = true
    The herald has been especially well-behaved since your little agreement. 
    
    *if respect > 55
        *fake_choice
            #He is only the Council's leader in title. I'm making the decisions now.
                *set council 1
                @{(becomemortal) And you plan to continue doing so, after you become mortal. It|It} is better this way.

                @{(becomemortal) You and Morpheus have gotten|You and Morpheus get} more free rein over your domains, and if Zeus doesn't like it, Hermes is the one who must face the consequences.
            #He is only the Council's leader in title. I'm making him defer to Iris.
                *set council 2
                The aide is a far better leader, and Hermes knows it. He has been more than happy to take whatever Iris says and roll with it.

                The best part is that, whenever Zeus doesn't like it, he's the one forced to deal with the consequences.
            #He is still the Council's leader, in title and in effect.
                *set council 3
                But he has certainly stepped up, and even allowed both you and Morpheus more free rein over your domains, Zeus's wishes be damned.

        *if favor
            And, should he step out of line anew, there's always that favor he owes you to call in. Plenty of unpleasant things you could make him do, while keeping his secret safe.
            *goto messengers3
        *else
            *goto messengers3
    *else
        *set council 3    
        But your choice to keep his involvement in Argus's release secret has been cause of much awkwardness within the Council. Iris has kept a respectful distance from you since.
        *if morpheusoutcome > 2
            And, while Morpheus readily admits Hermes has stepped up and even allowed the pair of you more free rein over your domains, he still gripes about it on the regular.
            *goto messengers3
        *else
            *set tense true
            Morpheus has noticed, and though he remains in the dark about what went down between you and the herald, his hatred for him grows stronger every time you gather.
            *goto messengers3
*else
    His bravery in battle, where he and the harpies minding him had cut down giants with fearsome might, had earned him his release from @{(hermespunishment) confinement|Tartarus|confinement|confimenet|confinement}.

    As for his place in the Council,
    *if respect > 55
        what did you, Morpheus and Iris decide?

        *fake_choice
            #To grant him his position of leader back.
                *set council 4 
                Yes, he had sicked Argus on Morpheus. But he had been punished for it.

                "I believe in second chances," Iris had said.

                "And I believe in making his eternity as miserable as possible," Morpheus had added. "Forcing him to deal with his father whenever I don't do what he wants, which will be [i]all[/i] the time, is a good place to start."
                *goto messengers3
            #To keep Iris as leader, but allow Hermes back into the Council.
                *set council 5
                *goto irisincharge
            #To keep Iris as leader, and Hermes out of the Council.
                *set council 6
                *set mustapologize true
                *goto irisincharge
            *if becomemortal = false
                #To make me their leader, and allow Hermes back into the Council.
                    *set council 7
                    *goto mcincharge
            *if becomemortal = false
                #To make me their leader, and keep Hermes out of the Council. 
                    *set council 8
                    *set mustapologize true
                    *goto mcincharge
    *else
        *set council 4
        *set tense true
        Iris had decided to grant him his position back, much to Morpheus's annoyance and your confusion. 

        "I believe in second chances," the aide had said, and, since they had been declared interim leader, that had been that.
        *goto messengers3

*label mcincharge

"You have always had the Council's best interests at heart," Iris had said.

"It's high time the Council had a leader that wasn't @{(olympusinfluence > 55) so completely under|under} Olympus's thumb," Morpheus had agreed.

And so had begun the Council's new dawn.

*if mustapologize = true
    *goto apology
*else
    *goto messengers3 

*label irisincharge

They have always had the Council's best interests at heart, and would never compromise the balance between the realms to make it so.

*if mustapologize = true
    *goto apology
*else
    *goto messengers3 

*label apology
*page_break

Alas, Hermes hadn't stopped hounding you until you had granted him an audience. 

@{(becomemortal) And what better occasion to do so than your final meeting?|"Well, herald, you have our attention, now stop wasting our precious time and speak," Morpheus says, waving for the herald to get on with it.}

Hermes's grey eyes dart between him and @{(council > 6) you|Iris} as he toys with the hem of his chitoniskos. His nervous energy has a different tinge, now. Less springy, more jagged.

"Fellow messengers," he begins. "Thank you for agreeing to hear me out. First and foremost, I wish to extend my apologies to Morpheus."
    
He tips his helm to the god of dreams, who crosses his arms before his chest. As though out of its own volition, his scarred wing twitches.

@{(injured) Then he turns his attention to you. "And to you, daughter of Hades, who also suffered Argus's wrath, and will forever bear the mark."|"I truly regret my actions, and the pain they have caused," Hermes adds.}
    
To his credit, he does look genuinely remorseful. @{(hermespunishment) Confinement|Tartarus|Confinement|Confimenet|Confinement} will do that to you, you suppose.

"I come before you, before all of you," Hermes adds, "not to ask that you allow me back into the Messengers' Council. I have broken your trust, and I don't deserve that honor. No, I have come before you to humbly ask, nay beg, for your forgiveness."

*page_break

Now that's something you never thought you'd ever hear. An Olympian, admitting wrongdoing and [i]apologizing[/i] before an audience, without, as far as you can tell, being made to do so by Zeus?

Interesting. 

"I will not grant you my forgiveness, not until you've earned it," Morpheus says, voice as hard as his face. Then he addresses you and Iris. "I say let him prove himself. Let him join us, not as a fully-fledged member, but as an aide. Run our errands, no matter how small or idle. And, best of all, deal with Zeus whenever we don't do what he pleases."

Iris's eyes flash green. "That sounds fair to me. What do you say, ${name}?"

*choice
    #I agree. @{(becomemortal) They're going to need all the help they can get, when I'm gone|We could use the extra hand}.
        *goto hermesstays
    #I agree. It would be fun to see Hermes humbled even further.
        *goto hermesstays
    #I refuse. Hermes doesn't deserve forgiveness, let alone a second chance at the Council.
        *set hermesnotthere true
        *goto hermesleaves
    *if giantsuccess = 2
        #I refuse. This is clearly a ploy from Zeus to regain his foothold in the Underworld.
            *set hermesnotthere true
            *goto hermesleaves

*label hermesleaves

"While I appreciate your attempt at contrition," you tell Hermes, "I do not accept your apology. And I do not wish for you to be allowed back into our ranks."

Morpheus and Iris nod.

Hermes's shoulders sag. His grey eyes are hollow when they meet yours, his voice too soft. "I understand."

Silence, heavy and gnarled, weighs down on the clearing as he drags himself to the Gate, and through it.
*goto messengers3

*label hermesstays

"I say Morpheus is right." You turn to Hermes. "You may stay, herald, and prove yourself to us."

His grey eyes glitter, his wings flit with some their usual speed. "Thank you."

*label messengers3
*page_break Get On With It

The meeting proceeds. Updates on worship are provided. Concerns around boosting the Leukans' morale are raised. @{(extramessenger) Your replacement is clued in on your final nightmare run, and what they'll have to do upon officially taking over|Plans to gather anew are arranged}.

When it's finally over and you bid one another farewell, you're

*fake_choice
    *if becomemortal
        #Glad I won't have to do any of it ever again after today.
    *if council > 6
        #Still reeling from all the work you've yet to do.
            Alas, such is the responsibility of the Council's leader.
    *if council < 7
        #Glad you're not the one at the head of the Council.
    #Ready to fling myself at the Lethe to clear my head.
    #Ready for @{(becomemortal) your final|a} cup of nectar and a nap.

*if chose = 3
    "Fancy a swim?" Morpheus asks, taking your hand in his, his rings cold against your palm.

    "Always."
    *goto lakeswim
*elseif chose = 4
    Returning home is a welcome blessing. 

    Averna and Zagreus are already there, playing petteia
    *if home = 8
        on the wooden table you placed in the makeshift courtyard, in a sunny spot that gets a nice breeze. 

        Beyond the cliff's edge, the waves roar and the gulls shriek, but they don't drown out your brother's accusations of cheating.
        *goto soloend
    *elseif home = 9
        on the marble table by the balcony.

        Beyond the railing, bees buzz and doves coo, but they don't drown out your brother's accusations of cheating.
        *goto soloend
    *else
        on the little table they claimed for themselves too long ago to argue about it now.

        Beyond the balcony, the souls flit and the damned cry, but they don't drown out your brother's accusations of cheating.
        *goto soloend
*else
    *if chose = 1
        Home beckons you forth, as does the god waiting for you there.
        *goto areshome
    *else
        With your messengers' duties done, there's nothing keeping you from returning to Theron's side.
        *goto theronhome

*label soloend

"You led me there on purpose," he accuses the lampad with a pout.

Her grin is sharp as a knife. "It's called strategy, hunter. You should try it sometime."

*if injuredzagreus = true
    Zagreus may have come close to losing his life on the battlefield-as proven by the the scar disappearing into the neck of his peplos-but the lampad refused to go easy on him.

    He seemed to prefer it that way.
    *goto soloend1
*else
    *goto soloend1

*label soloend1

The pair of them had taken to invading your space whenever it took their fancy.

*fake_choice
    #But I don't mind the company one bit.
    #I don't mind the company, most of the time.
    #Despite my efforts to discourage them.
        *set discourage true

Much has changed since you received Zeus's invitation to dine all those moons ago. 

But their presence is proof that some things are as they always have been. You @{(marriage < 4) have yet to find a suitor that meets your needs|remain happily unmarried}. You are still @{(nightmares < 4) happily doing the Fates' bidding|doing the Fates bidding, even if you can't help but question their reasonings}. Your parents @{(parents > 55) love and support you, even if they sometimes gripe about it|love you, even if it doesn't always feel like it}.

And, as you look for a place to hide @{(peacockbouquet) Hera's|Aphrodite's} hideous gift, you can't help but think that, for now at least, that's exactly how you like it.
*goto end

*label areshome

Upon arriving, however, you quickly realize he's been doing a lot more than waiting.

A small feast awaits you, spread over not one but two tables, and being eyed by the hatchlings pretending to nap by the hearth with a little too much interest.

"I thought you might be hungry," Ares says by way of greeting.

He's holding a pan that appears to contain even more food, and the apron @{(parents > 55) your father gave him is covered in flour|Zagreus gave him in the hopes of getting invited over for dinner more often is covered in flour}.

*if parents > 55
    It's only one of the many gifts he has received from your parents since the battle. The most impressive one, however, is currently hidden in a closet so the drakons stop trying to steal it.
    
    *gosub crown
    Your chest tightens at the memory.
    *goto areshome1
*else
    *goto areshome1

*label areshome1
*page_break

"Was this @{(peacockbouquet) my mother's|Aphrodite's} doing?" he asks, taking the @{(peacockbouquet) bouquet|swan} from you and ushering you into a chair.  

"Who else?"

He shakes his head and returns his attention to the caly oven. "I'm just finishing with the ambrosia cake."

You pour yourself a cup of nectar and watch him work. Not just because you enjoy the way he moves around the @{(home) kitchen|makeshift kitchen|makeshift kitchen|na|na|na|na|kitchen|makeshift kitchen|makeshift kitchen}, confident and content.

But because you can't believe how much this domesticity suits him.
*gosub fatetug

The nectar in the cup shifts, showing you glimpses of your future on the liquid's golden surface. 
*if marriage != 4
    @{(proposal) Ares, slipping a ring carved with an ambrosia flower onto your finger|Ares, slipping a ring carved with an ambrosia flower onto your finger while your family watches|Ares's dimpled grin, when you slip a ring carved with an ambrosia flower onto his finger}.
    *goto areshome2
*else
    *goto areshome2
*label areshome2
The hatchlings, grown and fanged and fearsome, but still hassling Ares to play catch and tug-of-war. Countless cups of nectar and plates of cake passed around this very table.
*if wantchildren
    A child with his hazel eyes and your face, reaching for your hand.
    *goto areshome3
*else
    *goto areshome3
*label areshome3
The scrolls you wrote to one another before this life found you, and the ones you will write to one another while in its embrace. 

Then the thread comes undone, and the Fates' grip on your awarenes loosens.

And as Ares settles in his seat before you, you can't help think of the twin souls you sometimes see in the Underworld. Bound by something stronger than death. Stronger than memory.

Something you finally understand.
*goto end

*label theronhome

You had waited until he had fallen asleep to slip out of bed and tend to your duties. 

But he's very much awake when you come upon @{(home > 7) the cabin on the edge of the cliff|the home you share}. Sat at @{(home > 7) a rickety wooden table in the makeshift courtyard|the table in his balcony}, whittling.     

*if parents > 55
    Beside him is the gift your parents granted him when your mother returned to the Underworld, almost brighter than the sun itself.
    *gosub crown
    The memory makes your chest tighten.
    *goto theronhome1
*else
    *goto theronhome1

*label theronhome1
*page_break

Theron glances up before you begin your descent, and is by your side before you sandals touch tile.

"What is [i]that[/i]?" he asks, gawking at @{(peacockbouquet) Hera's bouquet|Aphrodite's swan}.

You let him take it from you to examine closer.

"A token of @{(peacockbouquet) Hera's|Aphrodite's} appreciation, allegedly."

"I see. Tea?"

He's already disappearing inside with the @{(peacockbouquet) bouquet|swan}. If he were to toss it into the hearth while he poured you some tea, you wouldn't blame him.

You take a seat on what has become your chair, enjoying the suns's warmth and the sea breeze.

*if becomemortal
    After tonight, when you break your Stygian oath, both will feel different on your face.

    A face that will change. [i]Age[/i].

    *fake_choice
        #I'm looking forward to it.
            Theron had taken some convincing.
        #I'm a little nervous about it.
            Theron had taken some convincing.
        #I wish it hadn't taken this long.
            Alas, there were a few loose ends to tie, and Theron had taken some convincing.
    
    There had been many long conversations late into the night about why you were making this choice, and whether it was the right one.

    He didn't wish for you to give up such a big part of yourself, and feared resentment would take root inside you, wear away at your love for him and the life you're building together.

    But this is what you want. And you know exactly what Stygian oath you'll swear to prove it.

    "I swear I don't wish to become mortal," you'll say before Iris, and then there will be no doubt in his mind, just like there's no doubt in yours, that this is your fate.
    *goto theronhome2
*else
    Theron ought to leave for the shipyard soon, but perhaps you'll convince him to stay with you a little longer. To enjoy the time you have together, while you still have it.
    *goto theronhome2

*label theronhome2
*page_break

*gosub fatetug

The sky before you shifts, showing you glimpses of your future. Love, pain, laughter, @{(becomemortal) sorrow. Your eyes watering when meeting the sun, unused to the sting of its brightness|sorrow}. 
*if marriage = 4
    *goto theronend1
*else
    @{(proposal) Theron, slipping a ring carved with waves onto your finger|Theron, slipping a ring carved with waves onto your finger while your family watches|Theron's grin, when you slip a ring carved with waves onto his finger}
    *goto theronend1
*label theronend1
Your brother, as youthful and radiant as he is now, teasing the greying @{(becomemortal) woman you are becoming|man Theron has become}. 
*if wantchildren
    A child, with Theron's dark eyes and your face, reaching for your hand.
    *goto theronend2
*else
    *goto theronend2    
*label theronend2
@{(therondecision) Your bones shivering against the chill in the air. Theron's lips brushing your wrinkled cheek|Theron's lips brushing your cheek|Theron's lips brushing your smooth cheek}, his white beard scratching your skin.

*if therondecision < 3
    And, at the end of it all, two souls, roaming the Underworld together, bound by something stronger than death. 

    Stronger than memory.

    Then the thread comes undone, and the Fates' grip on your awarenes loosens. The sky returns to its blue and future-less state. And as Theron hands you your tea, you're susprised by how comforting you find the fact that it isn't just a good life awaiting the pair of you.
    
    It's a good death, too.
    *goto end
*else
    Your time together may not end in two souls, roaming the Underworld side by side for all eternity.

    But you are bound by something stronger than death, stronger than memory, all the same.
    *goto end

*label lakeswim
*page_break

The water is cool, the mist thick. 

*gosub fatetug

The lake's dark surface shifts, showing you glimpses of your future. The Dream Gate, swallowed by a sea of poppies and @{(flower) crocuses|daffodils|quince flowers|nightshades}. 
*if marriage = 4
    *goto lakeswim1
*else
    @{(proposal) Morpheus, slipping a ring carved with both your flowers onto your finger|Morpheus, slipping a ring carved with both your flowers onto your finger while your family watches|Morpheus's grin, when you slip a ring carved with both your flowers onto his finger}.
    *goto lakeswim1
*label lakeswim1
*if wantchildren
    A child with Morpheus's violet eyes and your face, reaching for your hand.
    *goto lakeswim2
*else
    *goto lakeswim2
*label lakeswim2
Ikelos as a grown god, showing you and Morpheus how far he has come with @{(hobby) the loom|under your rigorous training|the aulos|his petteia strategy}. Pale moths and shadow @{(epiali) snakes|bats|ravens|cats|spiders} weaving through the Halfrealm's currents, side by side.

Then the thread comes undone, and the Fates' grip on your awarenes loosens. On the lake's surface, where your future had shimmered bright as a gem, there is only a couple of souls' reflections.

They chase one another across the sky, never allowing the distance between them to grow too wide. Bound by something stronger than death. Stronger than memory.
*goto end

*label olympusrelationship

In the aftermath of the Battle of Leukas, relations between the Underworld and Olympus
*if (giantsuccess = 2) and (olympusinfluence > 55)
    *set olympusrelations 1
    haven't been as tense as you expected, considering the stunt you and your father pulled to end the carnage. 

    Zeus has yet to make good on his threat to restrict ambrosia shipments, though he @{(hermesleader) has been attempting to keep a close eye on the Messengers' Council via Hermes|hasn't stopped campaigning to reinstate Hermes as the leader of the Messengers' Council since the Giants' returned to their lands}.
    *return
*elseif (giantsuccess = 2) and (olympusinfluence < 55)
    *set olympusrelations 2
    have been rather tense. While convincing your father to take a stand against Zeus had put an end to the carnage, it had also put your realms at odds.

    Not only had Zeus made good on his threat to restrict ambrosia shipments, he had also @{(hermesleader) attempted to keep a tighter leash on the Messengers' Council via Hermes|campaigned to reinstate Hermes as the leader of the Messengers' Council as soon as the Giants' returned to their lands}.
    
    It isn't the worst bids to keep his foothold in your realm go, but it's also hardly worth worrying about.
    *return
*elseif (giantsuccess != 2) and (olympusinfluence > 55)
    *set olympusrelations 3
    have never been better. 

    *if badfight
        Failing to @{(giantfailure) convince Zeus to stop the carnage|convince your father to turn against Zeus|enlist Cerberus's help to win the fight|convince the Leukans to give the gods' strength|reach into your worship reserves to aid the fight}, hasn't stopped Zeus from singing your praises. Hera, too.

        @{(allformortals) All the minimal effort you pored into the feast must've impressed them. Or perhaps Zeus feels bad for being|all that effort you pored into the feast wasn't for nothing, even if he was} all too quick to destroy it.
        *return
    *else
        Not only that, but you have also become the realm's darling.
        
        Ever since @{(giantsuccess) you convinced him to stop the carnage|na|you and Cerberus helped secure victory|your stunt with Medea helped you secure victory|your miracle}, Zeus has been full of praise for you. Hera, too.

        @{(chose) The former has even been warmer to Ares, too|The latter has even warmed up to Theron, too|The latter has even warmed up to Morpheus, too|Zagreus is very jealous}.
        *return
*else
    *set olympusrelations 4
    remain as cordial as ever.

    *if giantfailure = 2
        You suppose you have your father to thank. If he had done what you wanted him to, if he had challenged Zeus in the open, it could've led to even more dire consequences than the carnage at the beach. 
        *return
    *elseif badfight = true
        Perhaps if you hadn't failed to @{(giantfailure) convince Zeus to stop the carnage|na|enlist Cerberus's help to win the fight|convince the Leukans to give the gods' strength|reach into your worship reserves to aid the fight}, you might've yet made your mark in Zeus's realm.
        *return
    *else
        If Zeus and Hera were impressed by your performance on the beach, they have yet to make it known.
        *return

*label leukasupdate

The island had @{(badfight) yet to fully recover from|made great progress since} the Battle of Leukas, as the Poets have grown fond of calling it.

The pantheon had worked hard to mend what had been broken.

The beach had been cleared of debris, Poseidon had labored over the cliffs, Aphrodite had @{(badfight) begun rebuilding the temple|Aphrodite had kept an eye on the temple}.

*if peoplepleaser < 55
    @{(badfight) Too|Despite your best efforts, too} much blood had been spilled, and it will take more than a spring and a harvest to scrub it from the island's shores. 
    
    As for its people's memories, they will remain forever stained.

    *if patron = true
        *goto patronupdate
    *else
        *return
*else
    The dead will forever be remembered @{(badfight) but the advent of a mighty spring and the dawn of a fruitful harvest had already helped ease the stain upon the island's memory|but they had been far and few between, thanks-in no small part-to you}.

    *if patron = true
        *goto patronupdate
    *else
        *return

*label patronupdate
*page_break

Their patron has been hard at work regardless.

*if (patron = true) and (becomemortal = true)
    Your tenure may have been short-lived but, during it, you made sure to focus on
    *goto patronchoice
*else
    You're still getting used to the role.
    
    So far, you've focused on
    *goto patronchoice

*label patronchoice

*fake_choice
    #Sparing the Leukans my nightmares.
        *set nonightmares true
        What better way to use the wiggle room your newfound title @{(becomemortal) granted|grants} you? Not only @{(becomemortal) did|does} it offer the Leukans some respite, but it @{(becomemortal) showed|shows} the rest of Hellas that it's under your protection.
    #Having my Epiali guard Leukas's shores.
        After the battle, @{(becomemortal) it was|it's} important for the rest of Hellas to know the island is under your protection. Shadowy daemons patrolling its coast @{(becomemortal) was the best way|ough} to get the message across.
    #Ensuring the Poets know about it.
        @{(becomemortal) Even though you will soon give up your immortality, you wish for your prowess as a goddess to live on|Your patronhood is only as strong as the story surrounding it}.
    *if becomemortal = false
        #Ensuring the temple is primarily dedicated to me.
            Not only does it encourage more worship, but it shows the pantheon the island is under your protection.

            The ego boost is merely a bonus.

*return

*label hadesmoping

Oh, how relentlessly he'd sulked while his wife had been away! How woefully he'd stalked his realm!

You lost count of how many times you'd found him brooding in a dark corner, or wandering your mother's orchard, wistfully staring at any pair of twin souls that flitted past him.

It had been @{(enjoyedhadesmoping) highly entertaining|quite harrowing}.
*return

*label crown

A crown of laurel just like the ones your family had worn at the Spring Feast, with pomegranate seeds glinting between the leaves, bestowed upon him by your parents. 

"To officially welcome you to our family," Persephone had told him.

@{(chose) Ares|Theron|Morpheus|na} had tilted his chin down, allowing her to place it upon his @{(chose) bronze hair|dark curls|silver hair|na}, barely able to contain the emotion on his face.
*return

*label fatetug

@{(chose) And as you bring the cup to your lips|And as the thought settles over you like a peaceful afternoon|And as you disrobe and welcome their embrace|na}, you feel a tug at the edge of your awareness. As though a thread had been tied around your mind, and was being pulled on. And you know, deep within your bones, that it's the Fates themselves holding it on the other end.
*return

*label end

*goto_scene ending